Imprimante_3D/chariot_X.scad

include <parametres.scad>

module chariot_X_empreinte(long = 100, courroie_larg = 10)
{
	//roulement linéaires
	translate([-LM8LUU_long/2, 0, -chariot_X_ecart_LM8LUU/2])
	{
		rotate([0, 90, 0])
		{LM8LUU();}
	}
	
	translate([-LM8LUU_long/2, 0, chariot_X_ecart_LM8LUU/2])
	{
		rotate([0, 90, 0])
		{LM8LUU();}
	}
	
	//axes pour l'empreinte on utilisera des axes de 9mm de diamètre, histoire d'avoir une marge
	axe_X_long = 500;
	translate([-long/2, 0, -chariot_X_ecart_LM8LUU/2])
	{
		rotate([0, 90, 0])
		{cylinder(d = 9, h = long);}
	}
	
	translate([-long/2, 0, chariot_X_ecart_LM8LUU/2])
	{
		rotate([0, 90, 0])
		{cylinder(d = 9, h = long);}
	}
	
	courroie_coupe_long = 8;
	translate([-long/2, chariot_X_ecart_delta_courroie1, -courroie_larg/2])
	{
		courroie(long = long/2 - courroie_coupe_long, larg = courroie_larg);
		
		translate([long - (long/2 - courroie_coupe_long), 0, 0])
		{courroie(long = long/2 - courroie_coupe_long, larg = courroie_larg);}
	}
	
	translate([-long/2, chariot_X_ecart_delta_courroie2, -courroie_larg/2])
	{
		courroie(long = long/2 - courroie_coupe_long, larg = courroie_larg);
		
		translate([long - (long/2 - courroie_coupe_long), 0, 0])
		{courroie(long = long/2 - courroie_coupe_long, larg = courroie_larg);}
	}
	
	//vis de fixation
	#translate([0, chariot_X[1] + 0.5, 0])
	{
		rotate([90, 0, 0])
		{
			fixations(entraxe1 = chariot_X[0] - 20, entraxe2 = chariot_X[2]/3 - 5, diam = 3, haut = 50);
			fixations(entraxe1 = chariot_X[0] - 20, entraxe2 = chariot_X[2]/3 - 5, diam = 6, haut = 3);
		}
	}
}

module chariot_X_support_laser()
{
	difference()
	{
		translate([laser_x/2, 0, 0])
		{cube([laser_x/2 + chariot_X_epaisseur, laser_y, chariot_X_ecart_LM8LUU + LM8LUU_diam_ext + chariot_X_marge[2]]);}
		
		translate([laser_x, 0, chariot_X_epaisseur])
		{
			rotate([0, 0, 90])
			{laser();}
		}
		
		translate([laser_x/2, laser_y/2, -1])
		{
			cylinder(d=laser_x, h = chariot_X_epaisseur + 2);
			cube([laser_x/2, laser_y/2 + 1, chariot_X_epaisseur + 2]);
		}
	}
}

module chariot_X()
{
	laser_delta = [LM8LUU_long + chariot_X_marge[0] - chariot_X_epaisseur, LM8LUU_diam_ext/2 + chariot_X_marge[1], chariot_X_epaisseur];

	difference()
	{
		union()
		{
			//socle principal
			cube(chariot_X);

			//support laser
			translate([chariot_X[0] - laser_x - chariot_X_epaisseur, LM8LUU_diam_ext/2 + chariot_X_marge[1], 0])
			{chariot_X_support_laser();}
		}
		
		translate([(LM8LUU_long + chariot_X_marge[0])/2, 0, (chariot_X_ecart_LM8LUU + LM8LUU_diam_ext + chariot_X_marge[2])/2])
		{
			chariot_X_empreinte();
//			#cube([LM8LUU_long + chariot_X_marge[0] + 1, 4.3, courroie_larg], center = true);
			scale([1.01, 1.01, 1.01])
			{cube([chariot_X[0], 1.8*courroie_ecart,chariot_X[2]/3], center = true);}
		}
	}
}

module courroie_machoire()
{
	difference()
	{
		color([0, 0, 0])
		{
			translate([chariot_X[0]/2, -0.3, chariot_X[2]/2])
			{cube([chariot_X[0], 1.8*courroie_ecart,chariot_X[2]/3], center = true);}
		}
		
		translate([(LM8LUU_long + chariot_X_marge[0])/2, 0, (chariot_X_ecart_LM8LUU + LM8LUU_diam_ext + chariot_X_marge[2])/2])
		{chariot_X_empreinte(courroie_larg = 30);}
	}
}

chariot_X_empreinte();